From ae6f971219b099821094c4e8bf59563edbd8f012 Mon Sep 17 00:00:00 2001
From: Folkert Kevelam <contact@pyllr.nl>
Date: Sat, 17 May 2025 23:05:26 +0200
Subject: [PATCH] Initial commit

---
 PKGBUILD | 86 ++++++++++++++++++++++++++++++++++++++++++++++++++++++++
 1 file changed, 86 insertions(+)
 create mode 100644 PKGBUILD

diff --git a/PKGBUILD b/PKGBUILD
new file mode 100644
index 0000000..fd7862b
--- /dev/null
+++ b/PKGBUILD
@@ -0,0 +1,86 @@
+# Maintainer: Rod Kay <rodakay5 at gmail dot com>
+
+# Contributor: Pierre-Marie de Rodat <pmderodat on #ada at freenode.net>
+# Contributor: Earnestly <zibeon AT googlemail.com>
+
+pkgname=gprbuild-bootstrap
+pkgdesc='Static GPRbuild to bootstrap XML/Ada and GPRbuild itself.'
+pkgver=25.0.0
+pkgrel=1
+epoch=1
+
+arch=(i686 x86_64)
+url=https://github.com/AdaCore/gprbuild
+license=(GPL3 custom)
+
+makedepends=(gcc-ada)
+provides=(gprbuild)
+
+source=("gprbuild-${pkgver}::https://github.com/AdaCore/gprbuild/archive/refs/tags/v$pkgver.tar.gz"
+        "gprconfig_kb-${pkgver}::https://github.com/AdaCore/gprconfig_kb/archive/refs/tags/v$pkgver.tar.gz"
+        "xmlada-${pkgver}::https://github.com/AdaCore/xmlada/archive/refs/tags/v$pkgver.tar.gz")
+
+sha256sums=(d12f94c1ec0b6e219f6b162f71f57129d22426e7798092f5f85b9ec2cc818bf1
+            802e6d38a3b110897924a9c16e143cb86360f2dde94bb5b9144c7c391e37b121
+            dbb5984a0931311c7a787a679ef4cfaeeedd357474a585dc170140ef2251dcca)
+
+_gprbuild_src=gprbuild-$pkgver
+_gprconfig_kb_src=gprconfig_kb-$pkgver
+_xmlada_src=xmlada-$pkgver
+
+
+prepare()
+{
+    cd $srcdir/$_gprbuild_src
+
+    # GPRbuild hard-codes references to /usr/libexec, but ArchLinux packages
+    # must use /usr/lib instead.
+    #
+    sed -i 's/libexec/lib/g'                        \
+    doinstall gprbuild.gpr                          \
+        $srcdir/$_gprconfig_kb_src/db/compilers.xml \
+        $srcdir/$_gprconfig_kb_src/db/linker.xml    \
+        $srcdir/$_gprconfig_kb_src/db/gnat.xml      \
+        $srcdir/$_gprconfig_kb_src/db/aamp.xml
+}
+
+
+build()
+{
+    cd $srcdir/$_gprbuild_src
+
+    CFLAGS="${CFLAGS//-Wformat}"
+    CFLAGS="${CFLAGS//-Werror=format-security}"
+
+    GNATMAKEFLAGS="$MAKEFLAGS"
+
+    ./bootstrap.sh                           \
+        --with-xmlada=$srcdir/$_xmlada_src   \
+        --with-kb=$srcdir/$_gprconfig_kb_src \
+        --build
+}
+
+
+package()
+{
+    cd $srcdir/$_gprbuild_src
+
+    env DESTDIR=$pkgdir                      \
+    ./bootstrap.sh                           \
+        --with-kb=$srcdir/$_gprconfig_kb_src \
+        --prefix=/usr                        \
+        --libexecdir=/lib                    \
+        --install
+
+    # Install the license.
+    #
+    install -D -m644 \
+       COPYING3      \
+       $pkgdir/usr/share/licenses/$pkgname/COPYING3
+
+    # Install the custom license.
+    #
+    install -D -m644   \
+       COPYING.RUNTIME \
+       $pkgdir/usr/share/licenses/$pkgname/COPYING.RUNTIME
+}